//******************************************************************************
// SCICHART® Copyright SciChart Ltd. 2011-2022. All rights reserved.
//
// Web: http://www.scichart.com
// Support: support@scichart.com
// Sales:   sales@scichart.com
//
// build.gradle is part of the SCICHART® Examples. Permission is hereby granted
// to modify, create derivative works, distribute and publish any part of this source
// code whether for commercial, private or personal use.
//
// The SCICHART® examples are distributed in the hope that they will be useful, but
// without any warranty. It is provided "AS IS" without warranty of any kind, either
// expressed or implied.
//******************************************************************************

plugins {
    id 'com.android.application'
    id 'kotlin-android'
    id 'com.github.triplet.play' version '3.7.0'
}

def apkVersionCode = APK_VERSION_CODE != '' ? APK_VERSION_CODE.toInteger() : rootProject.ext.versionCode
def apkVersionName = APK_VERSION_NAME != '' ? APK_VERSION_NAME : rootProject.ext.versionName

android {
    compileSdkVersion rootProject.ext.compileSdkVersion
    buildToolsVersion rootProject.ext.buildToolsVersion
    defaultConfig {
        applicationId "com.scichart.examples"
        minSdkVersion rootProject.ext.minSdkVersion
        targetSdkVersion rootProject.ext.compileSdkVersion

        versionCode apkVersionCode
        versionName apkVersionName

        multiDexEnabled true
    }
    compileOptions {
        sourceCompatibility rootProject.ext.sourceCompatibility
        targetCompatibility rootProject.ext.sourceCompatibility
    }

    signingConfigs {
        release {
            storeFile RELEASE_STORE_FILE != '' ? file(RELEASE_STORE_FILE) : null
            storePassword RELEASE_STORE_PASSWORD
            keyAlias RELEASE_KEY_ALIAS
            keyPassword RELEASE_KEY_PASSWORD
        }
    }

    buildTypes {
        debug {
            minifyEnabled false
        }

        release {
            minifyEnabled rootProject.ext.minifyEnabled
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }

        signed {
            initWith release

            debuggable false
            signingConfig signingConfigs.release

            // use release build since we don't provide releaseSigned builds
            matchingFallbacks = ['release']
        }
    }
    productFlavors {
    }

    lintOptions {
        checkReleaseBuilds false
    }

    buildFeatures {
        viewBinding true
    }
    namespace 'com.scichart.examples'
}

repositories {
    maven { url 'https://www.myget.org/F/abtsoftware-bleeding-edge/maven' }
    maven { url 'https://www.myget.org/F/abtsoftware/maven' }
    mavenCentral()
}

dependencies {
//@BEGINDEPENDS
    implementation (group: 'com.scichart.library', name: 'core', version: '4.5.4.4865', ext: 'aar')
    implementation (group: 'com.scichart.library', name: 'drawing', version: '4.5.4.4865', ext: 'aar')
    implementation (group: 'com.scichart.library', name: 'data', version: '4.5.4.4865', ext: 'aar')
    implementation (group: 'com.scichart.library', name: 'charting', version: '4.5.4.4865', ext: 'aar')
    implementation (group: 'com.scichart.library', name: 'charting3d', version: '4.5.4.4865', ext: 'aar')
    implementation (group: 'com.scichart.library', name: 'extensions', version: '4.5.4.4865', ext: 'aar')
    implementation (group: 'com.scichart.library', name: 'extensions3d', version: '4.5.4.4865', ext: 'aar')
//@ENDDEPENDS
    implementation 'androidx.appcompat:appcompat:1.4.0'
    implementation 'com.google.android.material:material:1.4.0'

    implementation 'androidx.constraintlayout:constraintlayout:2.1.2'

    implementation 'io.reactivex.rxjava2:rxandroid:2.1.1'
    implementation 'io.reactivex.rxjava2:rxjava:2.2.15'

    implementation 'com.trello.rxlifecycle3:rxlifecycle:3.1.0'
    implementation 'com.trello.rxlifecycle3:rxlifecycle-android:3.1.0'

    implementation 'com.github.twalcari:java-prettify:1.2.2'
    implementation "androidx.core:core-ktx:1.7.0"
    implementation "androidx.fragment:fragment-ktx:1.4.0"
    implementation 'androidx.multidex:multidex:2.0.1'
}

play {
    track.set("internal")
    defaultToAppBundles.set(true)
}