/*
 * Copyright (c) 2021 DuckDuckGo
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

plugins {
    id 'com.android.library'
    id 'kotlin-android'
    id 'com.squareup.anvil'
    id 'com.google.devtools.ksp' version "$ksp_version"
}

apply from: "$rootProject.projectDir/gradle/android-library.gradle"

dependencies {
    anvil project(path: ':anvil-compiler')
    implementation project(path: ':anvil-annotations')

    implementation project(path: ':di')
    implementation project(path: ':common-utils')
    implementation project(path: ':experiments-api')
    implementation project(path: ':statistics')
    implementation project(path: ':app-build-config-api')

    // Room
    implementation AndroidX.room.runtime
    implementation AndroidX.room.rxJava2
    implementation AndroidX.room.ktx
    ksp AndroidX.room.compiler

    // Apache commons
    implementation "org.apache.commons:commons-math3:_"

    implementation Kotlin.stdlib.jdk7
    implementation AndroidX.appCompat
    implementation JakeWharton.timber

    implementation KotlinX.coroutines.core

    implementation Google.dagger

    implementation Square.retrofit2.converter.moshi

    testImplementation(KotlinX.coroutines.test) {
        // https://github.com/Kotlin/kotlinx.coroutines/issues/2023
        // conflicts with mockito due to direct inclusion of byte buddy
        exclude group: "org.jetbrains.kotlinx", module: "kotlinx-coroutines-debug"
    }

    // Testing dependencies
    testImplementation project(path: ':common-test')
    testImplementation AndroidX.work.testing
    testImplementation AndroidX.room.testing
    testImplementation "org.mockito.kotlin:mockito-kotlin:_"
    testImplementation Testing.junit4
    testImplementation AndroidX.archCore.testing
    testImplementation AndroidX.core
    testImplementation AndroidX.test.ext.junit
    testImplementation "androidx.test:runner:_"
    testImplementation Testing.robolectric
    testImplementation CashApp.turbine

    androidTestImplementation project(path: ':common-test')
    testImplementation project(path: ':common-test')
}

android {
    anvil {
        generateDaggerFactories = true // default is false
    }
    testOptions {
        unitTests {
            includeAndroidResources = true
        }
    }
    defaultConfig {
        javaCompileOptions {
            annotationProcessorOptions {
                arguments = ["room.schemaLocation": "$projectDir/schemas".toString()]
            }
        }
    }
    sourceSets {
        test.assets.srcDirs += files("$projectDir/schemas".toString())
    }
    namespace 'com.duckduckgo.experiments.impl'
}