import io.gitlab.arturbosch.detekt.Detekt

plugins {
    id 'jacoco'
    alias(libs.plugins.detekt)
    alias(libs.plugins.ktlint)

    alias(libs.plugins.aboutlibraries) apply false
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.androidx.navigation.safeargs) apply false
    alias(libs.plugins.google.dagger.hilt.android) apply false
    alias(libs.plugins.kotlin.android) apply false
}

subprojects {
    apply plugin: "org.jlleitschuh.gradle.ktlint"
    apply from: "${project.rootDir}/jacoco.gradle"

    ktlint {
        verbose = true
        android = true
        outputToConsole = true
        disabledRules = ["max-line-length"]

        reporters {
            reporter "plain"
        }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

task detektCheck(type: Detekt) {
    parallel = true
    source = files(projectDir)
    include "**/*.kt"
    include "**/*.kts"
    exclude "**/resources/**"
    exclude "**/build/**"
    config.setFrom(files("$rootDir/detekt.yml"))
    buildUponDefaultConfig = false
}

ext {
    sdk_version = 33
}