plugins {
  id("me.saket.android.application")
  id("me.saket.kotlin.android")
  id("me.saket.compose")
  id("kotlin-parcelize")
}

android {
  namespace "me.saket.telephoto.sample"

  defaultConfig {
    applicationId namespace
    minSdkVersion 31
    compileSdk libs.versions.compileSdk.get().toInteger()
    versionCode 1
    versionName "1.0"
  }
  signingConfigs {
    release {
      keyAlias = "sample"
      keyPassword = "frappe-snivel-possible-downward"
      storeFile = file("release_keystore.jks")
      storePassword = "abstract-emperor-john-twill"
    }
  }
  buildTypes {
    release {
      minifyEnabled true
      signingConfig signingConfigs.debug
    }
    benchmark {
      initWith release
      matchingFallbacks = ['release']
      debuggable false
    }
  }
  lint {
    lintConfig = file("lint.xml")
    abortOnError = System.getenv("CI") == null
  }
  buildFeatures.compose = true
  composeOptions.kotlinCompilerExtensionVersion = libs.versions.androidx.compose.compiler.get()
}

dependencies {
  implementation(projects.flick)
  implementation(projects.zoomableImage.coil)
  implementation(projects.zoomableImage.glide)

  implementation(libs.androidx.appcompat)
  implementation(libs.androidx.ktx.core)
  implementation(libs.androidx.ktx.palette)
  implementation(libs.androidx.activity)
  implementation(libs.compose.ui.material3)
  implementation(libs.compose.ui.materialIcons)
  implementation(libs.accompanist.systemUi)

  implementation(libs.coil.compose)
  implementation(libs.coil.gif)

  implementation(libs.circuit.runtime)
  implementation(libs.circuit.backstack)
}