apply plugin: 'maven-publish'
apply plugin: 'signing'

afterEvaluate {
    publishing {
        publications {
            release(MavenPublication) {
                from components.release
                groupId "io.github.johannrosenberg"
                artifactId PUBLISH_ARTIFACT_ID
                version PUBLISH_VERSION

                pom {
                    name = PUBLISH_ARTIFACT_ID
                    description = "Android library to support responsive layouts using Jetpack Compose"
                    url = "https://github.com/johannrosenberg/jetmagic"
                    licenses {
                        license {
                            name = "GNU GENERAL PUBLIC LICENSE"
                            url = "http://www.gnu.org/licenses/gpl-3.0.html"
                        }
                    }
                    developers {
                        developer {
                            id = "Wirespec"
                            name = "Johann Rosenberg"
                            email = "rosenberg.stories@gmail.com"
                        }
                    }
                    scm {
                        connection = "scm:git:github.com/johannrosenberg/jetmagic.git"
                        developerConnection = "scm:git:ssh://github.com/johannrosenberg/jetmagic.git"
                        url = "https://github.com/johannrosenberg/jetmagic/tree/master"
                    }
                }
            }
        }
    }
}

signing {
    useInMemoryPgpKeys(
            rootProject.ext["signing.keyId"],
            rootProject.ext["signing.key"],
            rootProject.ext["signing.password"],
    )
    sign publishing.publications
}